Devi utilizzare il FOGLIO di EXCEL come se fosse un database :

1) ti connetti al foglio
2) utilizzi l'oggetto recordset per l'elaborazione
3) crei una query
4) Aggiorni il DB.

ESEMPIO

<%
'OGGETTO CONNESSIONE AL FILE DI EXCEL
dim ObjConXls
'OGGETTO CONNESSIONE AL DB
dim ObjConDb
'STRINGA DI CONNESIONE AL FILE DI EXCEL
dim StrconnXls
'STRINGA DI CONNESSIONE AL DB
dim Strconndb
'OGGETTO RECORDSET PER TRATTARE I DATI DEL FILE DI EXCEL
dim ObjRsXls
'QUERY PER L'APERTURA DEL FILE DI EXCEL
dim queryXls
'QUERY DI AGGIORNAMENTO PER IL DB TRAMITE OGGETTO COMMAND
dim QueryDb
'OGGETTO COMMAND PER L'AGGIORNAMENTO DEL DB
dim ObjCmdDb

'STRUTTURA FILE DI EXCEL
'CAMPO ID (Cella A1)
'CAMPO 1 NOME (cella B1)
'CAMPO 2 COGNOME(cella C1)

'STRUTTURA DB
'CAMPO 1 ID
'CAMPO 2 NOME
'CAMPO 3 COGNOME


set ObjConXls = server.CreateObject("ADODB.Connection")
set ObjConDb = server.CreateObject("ADODB.Connection")
set ObjRsXls = server.CreateObject("ADODB.Recordset")
set ObjCmdDb = server.CreateObject("ADODB.Command")

StrconnXls = "DBQ=" & server.MapPath("mdb-database/prova.xls") & ";" & "DRIVER={Microsoft Excel Driver (*.xls)};"
Strconndb = "driver={Microsoft Access Driver (*.mdb)};DBQ=" & server.MapPath("\mdb-database\prova.mdb")
ObjConXls.Open StrconnXls
ObjConDb.Open Strconndb
queryXls = "SELECT * FROM prova"
ObjRsXls.Open queryXls,ObjConXls

ObjCmdDb.ActiveConnection = ObjConDb

response.Write ObjRsXls.Fields("nome")

while not ObjRsXls.EOF

'CANCELLO LA QUERY PRECEDENTE
QueryDb = ""
'GENERO LA NUOVA QUERY
QueryDb = "INSERT INTO prova (nome,cognome) VALUES('" & ObjRsXls.Fields("nome") & "','" & ObjRsXls.Fields("cognome") & "')"
'AGGIORNO IL DB
ObjCmdDb.CommandText = QueryDb
ObjCmdDb.Execute
'MUOVO IL RECORDSET
ObjRsXls.MoveNext
wend
'CHIUDO LE CONNESSIONI
ObjConXls.Close
ObjConDb.Close
'FACCIO UN PO DI PULIZIA
set ObjRsXls = nothing
set ObjCmdDb = nothing
set ObjConDb = nothing
set ObjConXls = nothing
%>