Ciao...anche io ho buttato il sangue per sistemare sta cosa...però adesso funziona al 100 %
Allora, questo è il codice che produce il modulo per selezionare il file da uploadare e si chiama upload.htm
<html>
<head>
<title>UPLOAD FILE</title>
</head>
<body>
<!-- form selezione file -->
<table border=0 width=360 bgcolor="#40576f" cellspacing=1 align=center>
<tr>
<td width=400 align=center bgcolor="#7CB3FD"><FONT FACE="tahoma" color="#3a23d4" size=2><b>SELEZIONARE IL FILE PER L'UPLOAD</b></FONT></td>
</tr>
<tr>
<td width="400" height="0" bgcolor="#FFFFFF">
<form method="POST" enctype="multipart/form-data" action="upload.asp">
<p align="center"><b><font color="#000080" size="2" face="Arial"><br>
File: </font></b><input type="file" name="blob" size=30><br>
<input type="submit" name="Enter" value="Aggiungi">
</form>
</td>
</tr>
<tr>
<td width="400" height="10" bgcolor="#7CB3FD" align=right></td>
</tr>
</table>
<!-- form selezione file -->
</body>
</html>
Questa invece è il file upload.asp
<%
'variabili di configurazione
Dim folder
folder = "\public" 'directory sul server con accesso in scrittura
'fine variabili di configurazione
Response.Expires=0
Response.Buffer = TRUE
Response.Clear
Sub BuildUploadRequest(RequestBin)
PosBeg = 1
PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(13)))
boundary = MidB(RequestBin,PosBeg,PosEnd-PosBeg)
boundaryPos = InstrB(1,RequestBin,boundary)
Do until (boundaryPos=InstrB(RequestBin,boundary & getByteString("--")))
Dim UploadControl
Set UploadControl = CreateObject("Scripting.Dictionary")
'Get an object name
Pos = InstrB(BoundaryPos,RequestBin,getByteString("Content-Disposition"))
Pos = InstrB(Pos,RequestBin,getByteString("name="))
PosBeg = Pos+6
PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(34)))
Name = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
PosFile = InstrB(BoundaryPos,RequestBin,getByteString("filename="))
PosBound = InstrB(PosEnd,RequestBin,boundary)
If PosFile<>0 AND (PosFile<PosBound) Then
PosBeg = PosFile + 10
PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(34)))
FileName = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
UploadControl.Add "FileName", FileName
Pos = InstrB(PosEnd,RequestBin,getByteString("Content-Type:"))
PosBeg = Pos+14
PosEnd = InstrB(PosBeg,RequestBin,getByteString(chr(13)))
ContentType = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
UploadControl.Add "ContentType",ContentType
PosBeg = PosEnd+4
PosEnd = InstrB(PosBeg,RequestBin,boundary)-2
Value = MidB(RequestBin,PosBeg,PosEnd-PosBeg)
Else
Pos = InstrB(Pos,RequestBin,getByteString(chr(13)))
PosBeg = Pos+4
PosEnd = InstrB(PosBeg,RequestBin,boundary)-2
Value = getString(MidB(RequestBin,PosBeg,PosEnd-PosBeg))
End If
UploadControl.Add "Value" , Value
UploadRequest.Add name, UploadControl
BoundaryPos=InstrB(BoundaryPos+LenB(boundary),RequestBin,boundary)
Loop
End Sub
Function getByteString(StringStr)
For i = 1 to Len(StringStr)
char = Mid(StringStr,i,1)
getByteString = getByteString & chrB(AscB(char))
Next
End Function
Function getString(StringBin)
getString =""
For intCount = 1 to LenB(StringBin)
getString = getString & chr(AscB(MidB(StringBin,intCount,1)))
Next
End Function
byteCount = Request.TotalBytes
RequestBin = Request.BinaryRead(byteCount)
Dim UploadRequest
Set UploadRequest = CreateObject("Scripting.Dictionary")
BuildUploadRequest RequestBin
contentType = UploadRequest.Item("blob").Item("ContentType")
filepathname = UploadRequest.Item("blob").Item("FileName")
filename = Right(filepathname,Len(filepathname)-InstrRev(filepathname,"\"))
value = UploadRequest.Item("blob").Item("Value")
'Create FileSytemObject Component
Set ScriptObject = Server.CreateObject("Scripting.FileSystemObject")
'Create and Write to a File
Set MyFile = ScriptObject.CreateTextFile(Server.mappath(folder)&"\"&filename)
For i = 1 to LenB(value)
MyFile.Write chr(AscB(MidB(value,i,1)))
Next
session("nomefile") = filename
MyFile.Close
%>
<html>
<head>
<title>UPLOAD FILE</title>
</head>
<body>
<!-- conferma upload file -->
<table border=0 width=360 bgcolor="##7CB3FD" cellspacing=1 align=center>
<tr>
<td width=400 align=center><FONT FACE="verdana" color="#3a23d4" size=2><b>Il file <%=filename%> è stato uploadato con successo.</b></FONT></td>
</tr>
<tr>
<td width="400" height="30" align=center bgcolor="#FFFFFF"><a href="javascript:window.close();"><font face="verdana" size="2" color="#1800BB">Chiudi la finestra</font></a></td>
</tr>
<tr>
<td width="400" height="10" align=right></td>
</tr>
</table>
<!-- conferma upload file -->
</body>
</html>
Spero che ti sia utile !!
