Imports WIA
Imports System.Drawing
Imports System.IO
Imports System.Net

Partial Class _Default
    Inherits System.Web.UI.Page


    Private device As Device = Nothing
    Private jpegKey As Microsoft.Win32.RegistryKey
    Private jpegGuid As String


    Protected Sub Page_Init(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Init
        jpegKey = Microsoft.Win32.Registry.ClassesRoot.OpenSubKey("CLSID\{D2923B86-15F1-46FF-A19A-DE825F919576}\SupportedExtension\.jpg")
        jpegGuid = CType(jpegKey.GetValue("FormatGUID"), String)

        'find the right WIA device by Device ID
        'Look in the registry for the right ID after the GUID for your imaging device
        Dim manager As DeviceManager = New DeviceManagerClass
        For Each info As DeviceInfo In manager.DeviceInfos
            If (info.DeviceID = "{6BDD1FC6-810F-11D0-BEC7-08002BE2092F}\0015") Then
                device = info.Connect
                Exit For
            End If
        Next
    End Sub

    Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        If device IsNot Nothing Then
            Dim item As Item = device.ExecuteCommand(CommandID.wiaCommandTakePicture)
            For Each format As String In item.Formats
                If format = jpegGuid Then
                    Dim myImage As WIA.ImageFile = CType(item.Transfer(format), WIA.ImageFile)
                    Dim picture() As Byte = myImage.FileData.BinaryData
                    'Add the hour to the jpeg picture 
                    Dim ms As MemoryStream = New MemoryStream(picture)
                    Dim bmp As Bitmap = New Bitmap(ms)
                    Dim g As Graphics = Graphics.FromImage(bmp)
                    Dim strDate As String = (DateTime.Now.ToLongDateString + (" - " + DateTime.Now.ToLongTimeString))
                    Dim drawFormat As StringFormat = New StringFormat
                    drawFormat.Alignment = StringAlignment.Center
                    g.DrawString(strDate, New Font(FontFamily.GenericSansSerif, 12), New SolidBrush(Color.Black), New RectangleF(1, 1, 320, 240), drawFormat)
                    g.DrawString(strDate, New Font(FontFamily.GenericSansSerif, 12), New SolidBrush(Color.White), New RectangleF(0, 0, 320, 240), drawFormat)
                    bmp.Save(Response.OutputStream, System.Drawing.Imaging.ImageFormat.Jpeg)
                    g.Dispose()
                    bmp.Dispose()
                End If
            Next
        End If
    End Sub
End Class

<%@ Page Language="VB" AutoEventWireup="false" CodeFile="Default.aspx.vb" Inherits="_Default" ContentType="image/jpeg" %>