<!-- Include file for CAPTCHA configuration -->
<!-- #include file="CAPTCHA/CAPTCHA_configuration.asp" -->

<!-- Include file for CAPTCHA form processing --> 
<!-- #include file="CAPTCHA/CAPTCHA_process_form.asp" -->



<!--METADATA TYPE="typelib" UUID="CD000000-8B95-11D1-82DB-00C04FB1625D" NAME="CDO for Windows 2000 Type Library" -->
<!--METADATA TYPE="typelib" UUID="00000205-0000-0010-8000-00AA006D2EA4" NAME="ADODB Type Library" -->
<%
DIM corpoMessaggio, numeroCampi, invioA, invioDa, nomeDominio, indirizzoIp, modulo, browserSistemaOperativo
'
'------------inizio modifiche necessarie------------------
'
'#### in invioA e invioDa inserire il proprio indirizzo email
'#### Nota: dato che cdosys supporta questa notifica in caso di 
'#### errore riceverete un MAILER-DAEMON all'indirizzo in invioDa
'
invioA =  "info@mailxxxx.com"    
invioDa =  "info@mailxxxx.com"

'------------fine modifiche obbliatorie--------------------
'
'------------eventuali modifiche facoltative:-------------
'#### ricercare l'oggetto del messaggio, è nelle riga dopo '#### OGGETTO
'#### ricercare il corpo del messaggio, è nella riga dopo '#### CORPO
'#### ricercare nella penultima riga il file di risposta e modificarlo 
'#### con il persorso, il nome e l'estensione che desiderate utilizzare
'#### noi abbiamo utilizzato il nominativo: risposta.htm
'
'
nomeDominio = Request.ServerVariables("HTTP_HOST")
indirizzoIp = Request.ServerVariables("REMOTE_ADDR") 
modulo = Request.ServerVariables("HTTP_REFERER")
browserSistemaOperativo  = Request.ServerVariables("HTTP_USER_AGENT")

'rileva i campi del form
  
FOR numeroCampi = 1 TO (Request.Form.Count() - 1)
   IF NOT Request.Form(numeroCampi) = "" THEN
      corpoMessaggio = corpoMessaggio & vbCrLf & Request.Form.Key(numeroCampi) & " » " & Trim(Request.Form(numeroCampi))
   END IF
NEXT

'crea gli oggetti cdosys sul server e li gestisce
  
DIM iMsg, Flds, iConf

Set iMsg = CreateObject("CDO.Message")
Set iConf = CreateObject("CDO.Configuration")
Set Flds = iConf.Fields

Flds(cdoSendUsingMethod) = cdoSendUsingPort
Flds(cdoSMTPServer) = "localhost" 
Flds(cdoSMTPServerPort) = 25
Flds(cdoSMTPAuthenticate) = cdoAnonymous ' 0
Flds.Update

With iMsg
   Set .Configuration = iConf
   .To = invioA
   .From = Request.Form("email")
   .Sender = invioDa


'#### OGGETTO - questo sotto è l'oggetto che comparirà nel messaggio
   .Subject = "Contatto dal dominio " & nomeDominio


'#### CORPO - questo sotto è l'inizio del corpo messaggio (come stringa) 
'#### comando attualmente attivato 
   .TextBody = "Questi i dati inseriti nel modulo presente alla pagina " & modulo & " da utente con indirizzo IP " & indirizzoIp & "  browser e sistema operativo " & browserSistemaOperativo  & vbCrLf & corpoMessaggio & ""


'#### CORPO - questo è l'inizio del corpo messaggio (formattato in html)
'#### comando attualmente disattivato perchè è attivo come stringa
'   .HTMLBody = "<font face=verdana size=2>Questi i dati inseriti nel modulo presente alla pagina <b> " & modulo & " </b>da utente con indirizzo IP <b>" & indirizzoIp & " </b> browser e sistema operativo <b>" & browserSistemaOperativo  & "</b><br>" & corpoMessaggio 

   .Send
End With
%> 
<script>
document.location.replace('conferma_invio.asp');
</script>